[racket] Style or and/define

Nice, I wish Oleg had also defined let*-and, which is what I think you really want here: 

(define-syntax let*-and
  (syntax-rules ()
    [(_ ((x:id e:expr) (y:id f:expr) ...) body0:def-or-expr body1 ...)
     (let ((x:id e:expr))
       (and x:id (let*-and ((y:id f:expr) ...) body0:def-or-expr body1 ...)))]
    [(_ ((x:id) (y:id f:expr) ...) body0:def-or-expr body1 ...)
     (let ((x:id x:id))
       (and x:id (let*-and ((y:id f:expr) ...) body0:def-or-expr body1 ...)))]
    [(_ () body0:def-or-expr body1 ...)
     (let ()
       body0:def-or-expr
       body1 ...)]))

;; ----------------------------------------------------------------

(class object% 
  (super-new)
  
  (define/private (get-x-spot.v2 char-width)
    (let*-and ([char-width]
                    [dc (get-dc)]
                    [style (or (send (get-style-list) find-named-style "Standard")
                                  (send (get-style-list) find-named-style "Basic"))])
        (define-values (fnt) (send style get-font))
        (define-values (xw _1 _2 _3) (send dc get-text-extent "x" fnt))
        (+ left-padding (* xw char-width)))))

-- Matthias

  


On Jun 11, 2013, at 1:39 PM, Клочков Роман wrote:

> You may use srfi/2 http://docs.racket-lang.org/srfi-std/srfi-2.html
> 
> (require srfi/2)
> (define (get-x-spot char-width)
>   (and-let*
>    ([char-width]
>     [dc (get-dc)]
>     [style (or (send (get-style-list) find-named-style "Standard")
>                        (send (get-style-list) find-named-style "Basic"))])
>     (let*-values ([(fnt) (send style get-font)]
>                   [(xw _1 _2 _3) (send dc get-text-extent "x" fnt)])
>            (+ left-padding (* xw char-width))))))
> 
> 
> Вторник, 11 июня 2013, 18:49 +02:00 от Laurent <laurent.orseau at gmail.com>:
> When I see what Robby is forced to write when following the Style:
> https://github.com/plt/racket/commit/09d636c54573522449a6591c805b38f72b6f7da8#L4R963
> 
> I cannot help but think that something is wrong somewhere (it may not be the Style, and in case it wasn't clear I'm certainly not criticizing Robby's code).
> Using `let' and `and' instead, although being a bit better since it avoids all the [else #f], is not that big an improvement:
> 
> (define (get-x-spot char-width)
>   (and
>    char-width 
>    (let ([dc (get-dc)])
>      (and
>       dc
>       (let ([style (or (send (get-style-list) find-named-style "Standard")
>                        (send (get-style-list) find-named-style "Basic"))])
>         (and
>          style
>          (let*-values ([(fnt) (send style get-font)]
>                        [(xw _1 _2 _3) (send dc get-text-extent "x" fnt)])
>            (+ left-padding (* xw char-width)))))))))
> 
> 
> Actually I think here the right thing to do might be to allow for internal definitions inside `and':
> 
> (define (get-x-spot char-width)
>   (and char-width
>        (define dc (get-dc))
>        dc
>        (define style (or (send (get-style-list) find-named-style "Standard")
>                          (send (get-style-list) find-named-style "Basic")))
>        style
>        (define fnt (send style get-font))
>        (define-values (xw _1 _2 _3) (send dc get-text-extent "x" fnt))
>        (+ left-padding (* xw char-width))))
> 
> 
> Isn't it *much* more readable? (shorter, avoid rightward drift, less parens, vertical alignment)
> 
> Since it's not the first time I find the need for such internal definitions in `and', maybe this is something to consider for future addition to Racket? Or have some people already identified some problems with this idea?
> 
> I've played a bit with it if you want to try by your own:
> https://gist.github.com/Metaxal/5758394
> 
> (not sure I got it all good with syntax-parse though)
> 
> Laurent
> 
> ____________________
>   Racket Users list:
>   http://lists.racket-lang.org/users
> 
> 
> 
> -- 
> Роман Клочков
> ____________________
>  Racket Users list:
>  http://lists.racket-lang.org/users

-------------- next part --------------
An HTML attachment was scrubbed...
URL: <http://lists.racket-lang.org/users/archive/attachments/20130611/78a65da1/attachment-0001.html>