No subject

  http://www.cs.utah.edu/plt/snapshots/

(The latest snapshot does not yet fix the "aces.png" error that Sam
reported.)


If anyone else is interested in creating snapshots, I think the
makefile and instructions are ready to try out.

The "INSTALL.txt" file now has detailed information on site
configurations, including some example configuration files as the end.
As one more example, below is the configuration file for the snapshots
at "www.cs.utah.edu".

----------------------------------------

#lang distro-build/config
(require racket/format)

(define server-base-url (~a "http://www.cs.utah.edu/plt/snapshots"
                            "/" (current-stamp) "/"))
(define build-plt (path->string (current-directory)))

(define (make-machs make-name base pkgs)
  (sequential
   #:server "192.168.56.1"
   #:j 2
   #:dist-base base
   #:pkgs pkgs
   ;; ----------------------------------------
   ;; Mac OS X variants:
   (sequential
    #:server "localhost"
    #:repo build-plt
    ;; ----------------------------------------
    (machine
     #:name (make-name "Mac OS X" "Intel 64-bit")
     #:dir (string-append build-plt "/build/mac64")
     #:configure '("--enable-sdk6=/Developer/SDKs/MacOSX10.6.sdk"))
    ;; ----------------------------------------
    (machine
     #:name (make-name "Mac OS X" "Intel 32-bit")
     #:dir (string-append build-plt "/build/mac32")
     #:configure '("--enable-sdk=/Developer/SDKs/MacOSX10.4u.sdk"
		   "--disable-mac64")))
   ;; ----------------------------------------
   ;; Linux variants:
   (sequential
    ;; ----------------------------------------
    (machine
     #:name (make-name "Linux" "x86_64 32-bit, Precise Pangolin")
     #:vbox "ubuntu64"
     #:host "192.168.56.101"
     #:dist-suffix "precise")
    ;; ----------------------------------------
    (machine
     #:name (make-name "Linux" "i386 32-bit, Precise Pangolin")
     #:vbox "ubuntu32"
     #:host "192.168.56.102"
     #:dist-suffix "precise"))
   ;; ----------------------------------------
   ;; Windows variants:
   (sequential
    #:vbox "win7"
    #:host "192.168.56.103"
    #:port 2022
    #:platform 'windows
    #:bits 64
    ;; ----------------------------------------
    (machine
     #:name (make-name "Windows" "x64 64-bit")
     #:dir "c:\\Users\\Dr Racket\\build64")
    ;; ----------------------------------------
    (machine
     #:name (make-name "Windows" "x86 32-bit")
     #:dir "c:\\Users\\Dr Racket\\build32"
     #:vc "x86"))))

(define ((make-make-name s) platform detail)
  (string-append s " | " platform " | " detail))

(sequential
 #:dist-base-url server-base-url
 #:site-dest (build-path "/Users/racket/snapshots" (current-stamp))
 (make-machs
  (make-make-name "Minimal Racket")
  "min-racket"
  '())
 (sequential
  #:clean? #f
  (make-machs
   (make-make-name "Racket")
   "racket"
   '("main-distribution"))))